msgscript/flake.nix at master · numkem/msgscript · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
{
  description = "Run Lua function from nats subjects";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      version = "0.9.0";
      vendorHash = "sha256-Jer/ADurA+BwvAuuTjEycJNExBnobEs72ccQMmOqV1k=";

      mkPlugin =
        pkgs: name: path:
        pkgs.buildGoModule {
          name = "msgscript-plugin-${name}";

          inherit vendorHash;

          src = self;

          subPackages = [ path ];

          doUnpack = false;
          doCheck = false;

          buildPhase = ''
            go build -buildmode=plugin -o ${name}.so ${path}/main.go
          '';

          installPhase = ''
            mkdir $out
            cp ${name}.so $out/
          '';
        };
    in
    {
      packages.x86_64-linux =
        let
          pkgs = import nixpkgs { system = "x86_64-linux"; };
          lib = pkgs.lib;
          system = "x86_64-linux";
        in
        rec {
          default = server;

          cli = pkgs.callPackage ./nix/pkgs/cli.nix {
            inherit version vendorHash;
          };

          server = pkgs.callPackage ./nix/pkgs/server.nix {
            inherit version vendorHash;
          };

          runServer = pkgs.writeScript "msgscript" ''
            #!/usr/bin/env bash
            ${self.packages.${system}.server}/bin/msgscript -plugin ${allPlugins}/ $@
          '';

          runCli = pkgs.writeScript "msgscriptcli" ''
            #!/usr/bin/env bash
            ${self.packages.${system}.cli}/bin/msgscriptcli -plugin ${allPlugins}/ $@
          '';

          allPlugins = pkgs.symlinkJoin {
            name = "msgscript-all-plugins";
            paths = lib.attrValues plugins;
          };

          plugins =
            let
              pluginDirs = lib.remove "" (
                lib.mapAttrsToList (name: kind: if kind == "directory" then name else "") (
                  builtins.readDir "${self}/plugins/"
                )
              );
            in
            lib.genAttrs pluginDirs (name: mkPlugin pkgs name "${self}/plugins/${name}");
        };
      packages.aarch64-linux =
        let
          pkgs = import nixpkgs { system = "aarch64-linux"; };
          lib = pkgs.lib;
        in
        rec {
          cli = pkgs.callPackage ./nix/pkgs/cli.nix {
            inherit version vendorHash;
          };
          server = pkgs.callPackage ./nix/pkgs/server.nix {
            inherit version vendorHash;
          };
          default = server;

          allPlugins = pkgs.symlinkJoin {
            name = "msgscript-all-plugins";
            paths = lib.attrValues plugins;
          };

          plugins =
            let
              pluginDirs = lib.remove "" (
                lib.mapAttrsToList (name: kind: if kind == "directory" then name else "") (
                  builtins.readDir "${self}/plugins/"
                )
              );
            in
            lib.genAttrs pluginDirs (name: mkPlugin pkgs name "${self}/plugins/${name}");
        };

      apps =
        let
          mkApps = system: {
            server = {
              type = "app";
              program = "${self.packages.${system}.runServer}";
            };

            cli = {
              type = "app";
              program = "${self.packages.${system}.runCli}";
            };
          };
        in
        {
          "x86_64-linux" = mkApps "x86_64-linux";
          "aarch64-linux" = mkApps "aarch64-linux";
        };

      devShells.x86_64-linux.default =
        let
          pkgs = import nixpkgs { system = "x86_64-linux"; };
        in
        pkgs.mkShell {
          buildInputs = with pkgs; [
            go
            just
            etcd
            natscli
            nats-top
            pandoc

            # wasm
            tinygo
            wasmtime
            wasmtime.dev

            # Deps for podman
            pkg-config
            btrfs-progs
            gpgme

            # Server compose
            arion

            # LSPs
            gopls
            lua-language-server
          ];

          shellHook = ''
            export GOOS=linux
            export GOARCH=amd64
          '';
        };

      overlays.default = final: prev: {
        msgscript-cli = self.packages.${final.system}.cli;
        msgscript-server = self.packages.${final.system}.server;
      };

      nixosModules.default = import ./nix/modules/default.nix;
    };
}