Documentation idea / feature idea - style coefficients by pvalue

[donbowen]

Hi @benjann

I'm not sure if this is the right forum. I was trying to make a figure where the significance of individual coefficients was immediately clear. I had a lot of coefficients near 0 so it wasn't visually obvious which coefficients were statistically significant (xrescale didn't help given the constraints of what I was trying to show).

Your solutions for adding info in the markers (here) didn't work in my case because I had quite a few coefficients on the screen.

I wanted to style the coefficients by their pvalue. I didn't see anything on your site that explicitly did this (maybe I missed it!), but when I combed through everything, I was able to put enough together to figure this out:

sysuse auto
regress price mpg trunk length turn
coefplot (, if(@pval<=0.05) pstyle(p1) label("pval<.05"))   (, if(@pval>.05) pstyle(p2) label("pval>.05")) , drop(_cons)

This worked great, and I'm happy with it. In my case, there are many extra bells and whistles (multiple y variables, plotting interaction effects), but the above is the heart of things.

I wonder if adding a marker style by pval is something doable.

[benjann]

Hi Donald,
this is exactly how you would do this: also see here. coefplot is constructed in a way such that each (...) specification defines a series of estimates to be printed in the same style, so it would be difficult to add an option that sets marker styles depending on p-values automatically. It may be easier to write a little convenience utility to generate syntax as above that can then be plugged into coefplot. For example:

program stylebypval // returns local plots
    syntax [anything] [, Pstyles(numlist) Levels(numlist) * ]
    if !`: list sizeof levels'  local levels .05
    if !`: list sizeof pstyles' local pstyles 1 2
    // above 1st level
    gettoken l levels : levels
    local ps `pstyles'
    gettoken p ps : ps
    local plots/*
        */ (`anything', if(@pval>`l') label("p > `l'") pstyle(p`p') `options')
    local l0 `l'
    // intermediate levels
    foreach l of local levels {
        if !`: list sizeof ps' local ps `pstyles' // recycle styles
        gettoken p ps : ps
        local plots `plots'/*
            */ (`anything', if(@pval<=`l0'&@pval>`l') label("p {&le} `l0'")/*
             */ pstyle(p`p') `options')
        local l0 `l'
    }
    // last level
    if !`: list sizeof ps' local ps `pstyles' // recycle styles
    gettoken p ps : ps
    local plots `plots'/*
        */ (`anything', if(@pval<=`l0') label("p {&le} `l0'") pstyle(p`p') `options')
    // return result
    c_local plots `plots'
end

sysuse auto
regress price mpg trunk length turn

stylebypval
coefplot `plots', nooffsets drop(_cons)

stylebypval, p(1/4) l(.5 .15 .05)
coefplot `plots', nooffsets drop(_cons)

ben

[donbowen]

Thanks so much - I'll use this. And of course I missed the example on the site. Not sure if I was scanning for different keywords or just looking at the plots and didn't notice the (small) red coef for length in that plot.

Appreciate the work you put into coefplot... it's a great service!