Make FileFormats.MPS.Model an AbstractOptimizer

[odow]

@mlubin asks:

The other approach is to do what AmplNLWriter does an wrap the model in an optimizer:

https://github.com/jump-dev/AmplNLWriter.jl/blob/4e1edda22d272e3df27893eee7a7ca1e2da19ac9/src/AmplNLWriter.jl#L79-L80

[odow]

A minimal set of methods might be:

import MathOptInterface as MOI

struct Optimizer{M<:MOI.ModelLike} <: MOI.AbstractOptimizer
    inner::M
end

MOI.is_empty(model::Optimizer) = MOI.is_empty(model.inner)

MOI.empty!(model::Optimizer) = MOI.empty!(model.inner)

MOI.add_variable(model::Optimizer) = MOI.add_variable(model.inner)

function MOI.supports(model::Optimizer, attr::MOI.AbstractModelAttribute)
    return MOI.supports(model.inner, attr)
end

function MOI.get(model::Optimizer, attr::MOI.AbstractModelAttribute)
    return MOI.get(model.inner, attr)
end

function MOI.set(model::Optimizer, attr::MOI.AbstractModelAttribute, value)
    return MOI.set(model.inner, attr, value)
end

function MOI.get(model::Optimizer, attr::MOI.AbstractOptimizerAttribute)
    return MOI.get(model.inner, attr)
end

function MOI.get(model::Optimizer, ::MOI.SolverName)
    return "FileFormats.Optimizer"
end

function MOI.supports_constraint(
    model::Optimizer,
    ::Type{F},
    ::Type{S},
) where {F<:MOI.AbstractFunction,S<:MOI.AbstractSet}
    return MOI.supports_constraint(model.inner, F, S)
end

function MOI.add_constraint(
    model::Optimizer,
    f::MOI.AbstractFunction,
    s::MOI.AbstractSet,
)
    return MOI.add_constraint(model.inner, f, s)
end

using JuMP
model = direct_model(Optimizer(MOI.FileFormats.MPS.Model()))
@variable(model, 0 <= x[1:2] <= 1, Bin)
@constraint(model, sum(x) <= 1)
@objective(model, Max, sum(i * x[i] for i in 1:2))
display(model)
MOI.write_to_file(backend(model).inner, "file.mps")

[mlubin]

This is basically what I want to be able to do. How do we make it look nicer?

[odow]

Define "look nicer"

We could make it MOI.FileFormats.MPF.Optimizer() and MOI.write_to_file(backend(model), "file.mps")

[mlubin]

Yes, that would look nicer (after bikeshedding the Optimizer name). We probably want to do this in a way that shares the fake optimizer code between file formats so the same thing works for LP files, for example.

[blegat]

It's a bit unfortunate that we require the JuMP backend to be an AbstractOptimizer, we could also just let it be an AbstractModel, it's non-breaking