How to change sources in consult-buffer?

[Crandel]

I used Helm last 3-4 years, but some time ago I realize I use only a few commands on daily basis. So I found a Consult+Selectrum as lightweight replacement of Helm.

I used to helm-multi-files command which has almost the same output as consult-buffer. I changed sources using [C-right], [C-left] bindings. If I press [C-right] the top source changed from buffer list to recent-file list, next press changes top source to bookmark list, etc.

If I press [C-left] top source is recent-file list again.

Can I configure the same behavior for Consult(Selectrum)?

[minad]

There is no exact equivalence of the functionality you are asking for - cycling the sources. However for example Vertico has vertico-next/previous-group commands which allow you to jump between groups (Selectrum does not yet have this feature). These commands are bound to M-{} (remapping forward/backward-paragraph). We could also add such source cycling commands to Consult directly, which would work with consult-buffer. So far nobody has requested this feature and I am generally fine with having a slightly leaner feature set in comparison with Helm. But having such a cycling feature does not sound unreasonable to me - I may write a small prototype to see how it will look.

Another option is to implement it on the level of the completion UI - adding commands there which reorder the groups. The grouping feature is a bit more general than Consult, it is implemented even in Emacs 28. The advantage of implementing the feature in the completion UI directly would allow to work with all commands supporting groups, not only consult-buffer.

[minad]

I transferred the issue to minad/vertico#63, since I am convinced that this issue should be solved on the level of the completion UI. The same cycling solution can be used by both Selectrum and Vertico.

[Crandel]

Thank you for quick answer. Will wait for solution.

[minad]

There is one more feature I wanted to make you aware of - Consult Narrowing. This allows you to quickly narrow down to a source. For example if you have set consult-narrow-key to <, you can press <f, <m, <b to restrict to files, bookmarks or buffers only. To unrestrict you can press <<. Imo this feature is better than the cycling feature of helm since it allows you to go directly to the desired source. Of course this means adjusting your muscle memory in contrast to the Helm cycling ;)

I looked into how cycling could be implemented in Vertico and thought about this a bit more. And I have my doubts if it should be added because of the narrowing I just described, because of the additional complexity and also because we already have vertico-next/previous-group which allows you to jump between the groups in a way which is familiar from the paragraph navigation in normal buffers. I am not so sure I want to add multiple features which overlap a lot.

[Crandel]

Yes, I played a little bit with narrowing, like this, but for bookmarks I need additional keybinding. Cycle using narrowing could be also an option.

[minad]

What about using something like this? It allows you to cycle through all the narrowing keys.

(define-key minibuffer-local-map [C-left] #'consult-narrow-left)
(define-key minibuffer-local-map [C-right] #'consult-narrow-right)

(defun consult-narrow-left ()
  (interactive)
  (when consult--narrow-keys
    (consult-narrow
     (if consult--narrow
         (let ((idx (seq-position consult--narrow-keys
                                  (assq consult--narrow consult--narrow-keys))))
           (unless (eq idx 0)
             (car (nth (1- idx) consult--narrow-keys))))
       (caar (last consult--narrow-keys))))))

(defun consult-narrow-right ()
  (interactive)
  (when consult--narrow-keys
    (consult-narrow
     (if consult--narrow
         (let ((idx (seq-position consult--narrow-keys
                                  (assq consult--narrow consult--narrow-keys))))
           (unless (eq idx (1- (length consult--narrow-keys)))
             (car (nth (1+ idx) consult--narrow-keys))))
       (caar consult--narrow-keys)))))

EDIT: I added this to the Consult wiki for now - https://github.com/minad/consult/wiki#cycle-through-narrowing-keys.

[Crandel]

Perfect. Probably I will try Vertico instead of Selectrum too

[minad]

There is also minad/vertico#64, you can give this a try.

[Crandel]

Thank you @minad !