interpolasi function

[iingLK]

perlu ada juga untuk linear interpolasi, yang bisa mengeluarkan output yang duplikasi. dalam dynamic array.

[taruma]

Ini interpolasinya bisa berdasarkan excel yang sempat disinggung di G22.11.29.

[iingLK]

untuk yang satu kuadran dan dalam data terurut (gak boleh ada data double) bisa pake xmatch ama forecast linear aja.

untuk yang ada double, bisa pake xlookup, digabung dengan filter, terus pake take 1 dan take -1 untuk bisa ambil urutannya.

[taruma]

Berikut solusinya menggunakan XMATCH.

INTERPOLATE_LINEAR = LAMBDA(x, known_ys, known_xs,
    LET(
        known_xs, TOCOL(known_xs),
        known_ys, TOCOL(known_ys),
        nrow, ROWS(known_ys),
        known_table, HSTACK(known_xs, known_ys),
        sorted_table, SORT(known_table, 1),
        sorted_xs, CHOOSECOLS(sorted_table, 1),
        sorted_ys, CHOOSECOLS(sorted_table, 2),
        nearest_x, 
        IFS(
            x > MAX(sorted_xs), XMATCH(x, sorted_xs, -1),
            x < MIN(sorted_xs), XMATCH(x, sorted_xs, 1),
            TRUE, XMATCH(x, sorted_xs, -1)
        ),
        index_ys, IF(
            nearest_x < nrow,
            VSTACK(nearest_x, nearest_x + 1),
            VSTACK(nearest_x - 1, nearest_x)
        ),
        select_ys, CHOOSEROWS(sorted_ys, index_ys),
        select_xs, CHOOSEROWS(sorted_xs, index_ys),
        FORECAST.LINEAR(
            x, select_ys, select_xs
        )
    )
);