remove implicit cast from T to *const T

[andrewrk]

Now that #733 landed, T to *const T is less important. One might even make the case that such a cast is dangerous.

here are some examples I threw together of how this implicit cast can bite you in other parts of code:

const Contents = struct{
  value: u32,
};

const Container = struct{
  contents: Contents,
};

test "LHS: value, RHS: value" {
  var container = Container{ .contents = Contents{ .value = 1 } };
  var x: Contents = undefined;
  x = container.contents;
  container.contents.value = 2;
  std.debug.assert(x.value == 1);
}

test "LHS: pointer, RHS: value" {
  var container = Container{ .contents = Contents{ .value = 1 } };
  var x: *const Contents = undefined; // this is the only line that has changed!
  x = container.contents; // this line now has very different meaning
  container.contents.value = 2;
  std.debug.assert(x.value == 2);
}

/////////////

fn returnCopy() Contents {
  var container = Container{ .contents = Contents{ .value = 1 } };
  return container.contents; // returning copy
}

fn returnPointer() *const Contents {
  var container = Container{ .contents = Contents{ .value = 1 } };
  return container.contents; // looks the same, but very different meaning!
}

fn anotherFunction() void {
  var container = Container{ .contents = Contents{ .value = 999 } };
}

test "function returning copy" {
  const contents = returnCopy();
  anotherFunction();
  std.debug.assert(contents.value == 1);
}

test "function returning pointer" {
  const contents = returnPointer();
  anotherFunction();
  std.debug.warn("{}\n", contents.value); // this is garbage
}