[Modules] Updated Network/VPNGateways to new dependency approach

.github/workflows/ms.network.vpngateways.yml

@@ -106,8 +106,7 @@ jobs:
       - name: 'Using test file [${{ matrix.moduleTestFilePaths }}]'
         uses: ./.github/actions/templates/validateModuleDeployment
         with:
-          templateFilePath: '${{ env.modulePath }}/deploy.bicep'
-          parameterFilePath: '${{ env.modulePath }}/${{ matrix.moduleTestFilePaths }}'
+          templateFilePath: '${{ env.modulePath }}/${{ matrix.moduleTestFilePaths }}'
           location: '${{ env.location }}'
           resourceGroupName: '${{ env.resourceGroupName }}'
           subscriptionId: '${{ secrets.ARM_SUBSCRIPTION_ID }}'

modules/Microsoft.Network/vpnGateways/.test/common/dependencies.bicep

@@ -0,0 +1,49 @@
+@description('Optional. The location to deploy resources to.')
+param location string = resourceGroup().location
+
+@description('Optional. The name of the Virtual Hub to create.')
+param virtualHubName string
+
+@description('Optional. The name of the VPN Site to create.')
+param vpnSiteName string
+
+@description('Required. The name of the virtual WAN to create.')
+param virtualWANName string
+
+resource virtualWan 'Microsoft.Network/virtualWans@2021-05-01' = {
+  name: virtualWANName
+  location: location
+}
+
+resource virtualHub 'Microsoft.Network/virtualHubs@2022-01-01' = {
+  name: virtualHubName
+  location: location
+  properties: {
+    virtualWan: {
+      id: virtualWan.id
+    }
+    addressPrefix: '10.0.0.0/24'
+  }
+}
+
+resource vpnSite 'Microsoft.Network/vpnSites@2022-01-01' = {
+  name: vpnSiteName
+  location: location
+  properties: {
+    virtualWan: {
+      id: virtualWan.id
+    }
+    addressSpace: {
+      addressPrefixes: [
+        '10.1.0.0/16'
+      ]
+    }
+    ipAddress: '10.1.0.0'
+  }
+}
+
+@description('The resource ID of the created Virtual Hub.')
+output virtualHubResourceId string = virtualHub.id
+
+@description('The resource ID of the created VPN site.')
+output vpnSiteResourceId string = vpnSite.id

modules/Microsoft.Network/vpnGateways/.test/common/deploy.test.bicep

@@ -0,0 +1,83 @@
+targetScope = 'subscription'
+
+// ========== //
+// Parameters //
+// ========== //
+@description('Optional. The name of the resource group to deploy for testing purposes.')
+@maxLength(90)
+param resourceGroupName string = 'ms.network.vpngateways-${serviceShort}-rg'
+
+@description('Optional. The location to deploy resources to.')
+param location string = deployment().location
+
+@description('Optional. A short identifier for the kind of deployment. Should be kept short to not run into resource-name length-constraints.')
+param serviceShort string = 'nvgcom'
+
+// =========== //
+// Deployments //
+// =========== //
+
+// General resources
+// =================
+resource resourceGroup 'Microsoft.Resources/resourceGroups@2021-04-01' = {
+  name: resourceGroupName
+  location: location
+}
+
+module resourceGroupResources 'dependencies.bicep' = {
+  scope: resourceGroup
+  name: '${uniqueString(deployment().name, location)}-paramNested'
+  params: {
+    virtualHubName: 'dep-<<namePrefix>>-vh-${serviceShort}'
+    virtualWANName: 'dep-<<namePrefix>>-vw-${serviceShort}'
+    vpnSiteName: 'dep-<<namePrefix>>-vs-${serviceShort}'
+  }
+}
+
+// ============== //
+// Test Execution //
+// ============== //
+module testDeployment '../../deploy.bicep' = {
+  scope: resourceGroup
+  name: '${uniqueString(deployment().name)}-test-${serviceShort}'
+  params: {
+    name: '<<namePrefix>>${serviceShort}001'
+    virtualHubResourceId: resourceGroupResources.outputs.virtualHubResourceId
+    bgpSettings: {
+      asn: 65515
+      peerWeight: 0
+    }
+    connections: [
+      {
+        connectionBandwidth: 100
+        enableBgp: false
+        name: 'Connection-${last(split(resourceGroupResources.outputs.vpnSiteResourceId, '/'))}'
+        remoteVpnSiteResourceId: resourceGroupResources.outputs.vpnSiteResourceId
+        enableInternetSecurity: true
+        vpnConnectionProtocolType: 'IKEv2'
+        enableRateLimiting: false
+        useLocalAzureIpAddress: false
+        usePolicyBasedTrafficSelectors: false
+        routingWeight: 0
+      }
+    ]
+    lock: 'CanNotDelete'
+    natRules: [
+      {
+        externalMappings: [
+          {
+            addressSpace: '192.168.21.0/24'
+          }
+        ]
+        internalMappings: [
+          {
+            addressSpace: '10.4.0.0/24'
+          }
+        ]
+        mode: 'EgressSnat'
+        name: 'natRule1'
+        type: 'Static'
+      }
+    ]
+  }
+}

modules/Microsoft.Network/vpnGateways/.test/min/dependencies.bicep

@@ -0,0 +1,27 @@
+@description('Optional. The location to deploy resources to.')
+param location string = resourceGroup().location
+
+@description('Optional. The name of the Virtual Hub to create.')
+param virtualHubName string
+
+@description('Required. The name of the virtual WAN to create.')
+param virtualWANName string
+
+resource virtualWan 'Microsoft.Network/virtualWans@2021-05-01' = {
+  name: virtualWANName
+  location: location
+}
+
+resource virtualHub 'Microsoft.Network/virtualHubs@2022-01-01' = {
+  name: virtualHubName
+  location: location
+  properties: {
+    virtualWan: {
+      id: virtualWan.id
+    }
+    addressPrefix: '10.1.0.0/16'
+  }
+}
+
+@description('The resource ID of the created Virtual Hub.')
+output virtualHubResourceId string = virtualHub.id

modules/Microsoft.Network/vpnGateways/.test/min/deploy.test.bicep

@@ -0,0 +1,47 @@
+targetScope = 'subscription'
+
+// ========== //
+// Parameters //
+// ========== //
+@description('Optional. The name of the resource group to deploy for testing purposes.')
+@maxLength(90)
+param resourceGroupName string = 'ms.network.vpngateways-${serviceShort}-rg'
+
+@description('Optional. The location to deploy resources to.')
+param location string = deployment().location
+
+@description('Optional. A short identifier for the kind of deployment. Should be kept short to not run into resource-name length-constraints.')
+param serviceShort string = 'nvgmin'
+
+// =========== //
+// Deployments //
+// =========== //
+
+// General resources
+// =================
+resource resourceGroup 'Microsoft.Resources/resourceGroups@2021-04-01' = {
+  name: resourceGroupName
+  location: location
+}
+
+module resourceGroupResources 'dependencies.bicep' = {
+  scope: resourceGroup
+  name: '${uniqueString(deployment().name, location)}-paramNested'
+  params: {
+    virtualHubName: 'dep-<<namePrefix>>-vh-${serviceShort}'
+    virtualWANName: 'dep-<<namePrefix>>-vw-${serviceShort}'
+  }
+}
+
+// ============== //
+// Test Execution //
+// ============== //
+
+module testDeployment '../../deploy.bicep' = {
+  scope: resourceGroup
+  name: '${uniqueString(deployment().name)}-test-${serviceShort}'
+  params: {
+    name: '<<namePrefix>>${serviceShort}001'
+    virtualHubResourceId: resourceGroupResources.outputs.virtualHubResourceId
+  }
+}